用批处理删除N天前或指定日期时间(前后)创建(或修改)的文件

核心代码：

@echo off
:: by oicu#lsxk.org
:: 15:17 2011-1-13

:: 如果只是删除指定日期或N天前修改的文件，用forfiles即可
FORFILES /P "C:测试目录" /S /M *.log /D -3 /C "cmd /c if @isdir==FALSE echo del @file"
:: 指定日期（包含）前修改的文件：/D -yyyy/mm/dd

:: 以下是流水账
:: 使用限制：控制面板里设定日期格式为中文(中国)
:: 只有dir /tc才能查看到文件创建时间，默认dir都是dir /tw
:: 为了取出创建时间，只好用两次for+find，肯定很慢。

cd /d 你的目录
:: 如果要包含子目录，用for /r . %%a in (*)

:: 显示文件修改时间
for %%a in (*) do echo "%%~ta"
:: 中文格式时相当于
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tw "%%a" ^| find /i "%%~nxa"'
) do echo "%%b %%c"

:: 删除某个时间后修改过的文件(这个简单)
for %%a in (*) do if "%%~ta" gtr "2008-04-01" echo del "%%a"

:: 这个才是显示文件创建时间
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tc "%%a" ^| find /i "%%~nxa"'
) do echo "%%b %%c"

:: 删除某个时间之后创建的文件，如果要删除某个时间之前创建的，更改两
:: 处gtr为lss。除了日期外，增加判断时间，可以去掉else段。
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tc "%%a" ^| find /i "%%~nxa"') do (
  if "%%b" gtr "2010-12-15" (
    echo del "%%a"
  ) else (
    if "%%b" equ "2010-12-15" if "%%c" gtr "14:50" echo del "%%a"
  )
)

:: 用批处理计算时间受到系统的日期格式限制，影响到用set取某一字段的值，
:: 批处理计算时间方法过于复杂，要么只用vbs脚本删除文件，要么用批处理
:: 配合vbs脚本删除。

:: 取10天之前的日期，取回放入变量OldDate
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f %%a in ('cscript /nologo GetOldDate.vbs') do set OldDate=%%a
echo %OldDate%
del GetOldDate.vbs

:: VBScript里没有Format函数，Year、Month、Day等函数取数值后也要处理小
:: 于10的数字，只能用下面的方法整理日期格式
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f "tokens=1,2,3* delims=-/. " %%i in ('cscript /nologo GetOldDate.vbs') do (
  set y=%%i
  set m=%%j
  set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set OldDate=%y%-%m%-%d%
echo %OldDate%
del GetOldDate.vbs


:: 综合上文，最后得到我们想要的结果
:: 删除10天前创建的旧文件(不含子目录)
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f "tokens=1,2,3* delims=-/. " %%i in ('cscript /nologo GetOldDate.vbs') do (
  set y=%%i
  set m=%%j
  set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set OldDate=%y%-%m%-%d%
del GetOldDate.vbs
for %%a in (*) do for /f "tokens=1,2* delims= " %%b in (
'dir /tc "%%a" ^| find /i "%%~nxa"') do (
  if "%%b" lss "%OldDate%" echo del "%%a"
)

:: 删除10天前修改的旧文件(不含子目录)
echo wscript.echo dateadd("d",-10,date)>GetOldDate.vbs
for /f "tokens=1,2,3* delims=-/. " %%i in ('cscript /nologo GetOldDate.vbs') do (
  set y=%%i
  set m=%%j
  set d=%%k
)
if %m% LSS 10 set m=0%m%
if %d% LSS 10 set d=0%d%
set OldDate=%y%-%m%-%d%
del GetOldDate.vbs
for %%a in (*) do if "%%~ta" lss "%OldDate%" echo del "%%a"


:: 本文全部用echo del代替del，只是显示要删除的文件，并不实际删除。

pause
goto :eof

批处理处理文本文件去重复实现代码
最近需要将重复的内容去掉，所以就想到了使用bat或vbs实现，没想到网上已经有人写好了，测试也正好学习一下使用方法：把文本拖到批处理上就行了

批处理入门手册之批处理常用DOS命令篇(echo、rem、cd、dir)
1.1学习echoremcddir命令学习要点：1。显示信息：echo2。注释语句：rem3。目录切换：cd4。列文件名：dir一、显示信息：echo在学习echo命令前我们先在C盘下建

批处理入门手册之批处理常用DOS命令篇(attrib、del、copy、xcopy)
1.2学习attribdelcopyxcopy命令学习要点：1。设置文件属性：attrib2。删除命令：del3。复制文件：copy4。复制文件(夹)：xcopy一、设置文件属性：attrib显示或更